覚書 その3 excelマクロとjwwの外部変更を連動

 excelのマクロとjwwが連動できそう。

さらに手間が簡略できそう。

エクセルの所定のセルに加工寸法を入力して、

jwwボタンを押すと、下記のマクロが発動

外部変更が起動して、自動作図する。

Public Sub ExecuteExternalTransformation()

    Dim PythonExe As String

    Dim PythonScript As String

    Dim BatchFile As String

    Dim DXFFile As String

    Dim ModuleValue As Double

    Dim PressureAngle As Double

    Dim ToothHeight As Double

    Dim ToothTopWidth As Double

    Dim RetVal As Variant

    ' Pythonの実行ファイルのパス

    PythonExe = "C:\Users\yamat\AppData\Local\Programs\Python\Python313\python.exe"

    

    ' Pythonスクリプトのパス

    PythonScript = "C:\jww\hagirichan.py"

    

    ' DXFファイルのパス

    DXFFile = "C:\jww\gear_teeth2.dxf"

    

    ' バッチファイルのパス

    BatchFile = "C:\jww\hagirichan.bat"

    

    ' 必要な値をExcelシートから取得

    With ThisWorkbook.Sheets("歯切り")

        ModuleValue = .Range("G18").Value  ' モジュール値

        PressureAngle = .Range("G19").Value  ' 圧力角

        ToothHeight = .Range("H22").Value  ' 歯丈

        ToothTopWidth = .Range("G29").Value  ' 歯先幅

    End With

    

    ' バッチファイルを生成

    Dim FileNum As Integer

    FileNum = FreeFile

    Open BatchFile For Output As #FileNum

    Print #FileNum, "REM#jww 外部変形バッチファイル"

    Print #FileNum, """" & PythonExe & """ """ & PythonScript & """ " & _

                    ModuleValue & " " & PressureAngle & " " & ToothHeight & " " & ToothTopWidth

    Print #FileNum, "SET DXF_FILE=""" & DXFFile & """"

    Print #FileNum, "START """" ""C:\jww\Jw_win.exe"" %DXF_FILE%"

    Close #FileNum

    

    ' バッチファイルを実行

    RetVal = Shell(BatchFile, vbNormalFocus)

    

    ' 実行完了後の確認

    MsgBox "外部変形を実行しました。DXFファイルを確認してください。", vbInformation

End Sub

次は自動作図したものに、寸法が記入されるといいなと画策。

jww側の設定だから、作図時に寸法線指定して作図なのかな・・・わからん。